

1 GOSUB61000
4 DIMBE$(100)
5 SS=0
6 TU=0:PI=0:LA=0:SE=0:B=0:BU=0:T1=0:T2=0:T3=0:SA=0:BC=0:BE=0:D=0:TR=0:KA=0:CU=0
7 FORI=1TO5:A=INT(9*RND(1))+1:CU=CU+A:NEXT
10 DATA 76,24,1,177,251,145,251,200,208,249,230,252,202,208,244,96,120,160,0,169
12 DATA 160,132,251,133,252,162,32,32,11,1,169,224,132,251,133,252,162,32,32,11
14 DATA 1,169,53,133,1,88,96:FORI=264TO310:READX:POKEI,X:NEXT:SYS264
16 FORI=710TO730:READX:POKEI,X:NEXT
18 DATA208,3,76,29,168,32,192,2,32,19,166,56,165,95,233,1,164,96,76,36,168
20 POKE40996,197:POKE40997,2:POKE1,54
22 FORI=43168TO43170:READX:POKEI,X:NEXT
24 FORI=704TO709:READX:POKEI,X:NEXT
26 DATA 32,192,2,32,138,173,76,247,183
30 GOSUB52000:REM TABELLEN DEFINIEREN
100 ZN=1:GOTO1130


1000 REM A C T I O N M O D U L
1010 GOSUB50000:REM BEFEHLSEINGABE
1100 REM GEHE --------------------------
1105 IFVE<1ORVE>10THEN1200
1106 IFVE=9ANDZN=29ANDGE(16)=-1THENPRINT"DIE SCHIFFSSCHRAUBE IST SO SCHWER,"
1107 IFVE=9ANDZN=29ANDGE(16)=-1THENPRINT"DAS ICH NICHT KLETTERN KANN!":GOTO1000
1110 IFRI(VE)=0THENPRINT"IN DIESE RICHTUNG FUEHRT KEIN WEG!":VE=0:GOTO1200
1120 ZN=RI(VE):PRINT""
1130 REM
1140 RESTORE10000+ZN*100
1150 FORI=1TO10:READRI(I):NEXT
1155 GOSUB10000+ZN*100
1160 PRINT"MOEGLICHE RICHTUNGEN : ";
1165 IC=0:FORI=1TO10:IFRI(I)<>0THENPRINTVE$(I);", ";:IC=1
1170 NEXTI
1175 IFIC=0THENPRINT"KEINE."
1180 IFIC=1THENPRINT"."
1185 PRINT"ICH SEHE : ";
1186 IC=0:FORI=1TOOZ:IFOO(I)=ZNTHENPRINTOB$(I);", ";:IC=1
1187 NEXT
1188 FORI=1TOGZ:IFGE(I)=ZNTHENPRINTGE$(I);", ";:IC=1
1190 NEXT
1192 IFIC=0THENPRINT"NICHTS BESONDERES."
1194 IFIC=1THENPRINT"."
1196 PRINT"----------------------------------------"
1200 REM


2000 REM ALLGEMEINE ACTION -------------

2100 REM NIMM --------------------------
2110 IFVE<>11THEN2200
2111 TR=TR+1:IFTR>4THENTR=4:PRINT"ICH KANN NICHT NOCH MEHR TRAGEN!":GOTO1000
2112 IFG1=16ANDSS=0THENPRINT"SIE SITZT FEST.":GOTO1000
2113 IFOB<>0ANDG1<>0THENOB=0
2115 IFG1=16ANDGE(16)=-3ANDGE(15)=-1THENGE(16)=-1:GOTO2200
2116 IFG1=16ANDGE(16)=-3ANDGE(15)<>-1THENPRINT"WAS SOLL ICH NEHMEN?":GOTO1000
2117 IFOO(OB)=ZNTHENPRINT"DAS IST MIR LEIDER ZU SCHWER.":TR=TR-1:GOTO2200
2120 IFGE(G1)<>ZNTHENPRINT"DAS SEHE ICH HIER LEIDER NICHT!":TR=TR-1:GOTO2200
2125 IFGE(G1)=-1THENPRINT"DAS HABE ICH DOCH SCHON LAENGST!":TR=TR-1:GOTO2200
2130 IFGE(G1)=ZNTHENGE(G1)=-1:PRINT"OK."

2200 REM INVENTUR ----------------------
2205 IFVE<>61THEN2300
2210 PRINT"ICH HABE:"
2220 IC=0:FORI=1TOGZ:IFGE(I)=-1THENPRINTGE$(I):IC=1
2225 NEXT
2230 IFIC=0THENPRINT"NICHTS."
2235 IFIC=1THENPRINT"DAS IST ALLES."

2300 REM LEGE --------------------------
2305 IF VE<>13THEN2400
2306 IFTR=0THENPRINT"ABER ICH HABE DOCH GAR NICHTS!":GOTO3100
2308 TR=TR-1
2310 IFGE(G1)<>-1THENPRINT"DAS HABE ICH ZWAR NICHT, ABER DAS"
2311 IFGE(G1)<>-1THENPRINT"IST JA AUCH SCHON EGAL.":TR=TR+1:GOTO3100
2312 IFG1=16ANDGE(16)=-1ANDGE(15)<>-1THENGE(16)=ZN:GOTO3100
2313 IFG1=16ANDGE(16)=-1ANDGE(15)=-1THENPRINT"ICH HABE DIE SCHIFFSSCHRAUBE IN"
2314 IFG1=16ANDGE(16)=-1ANDGE(15)=-1THENPRINT"DEN BEUTEL GESTECKT!":GE(16)=-3:GOTO3100
2320 IFGE(G1)=-1THENGE(G1)=ZN:PRINT"OK.":GOTO3100

2400 REM UNTERSUCHE --------------------
2405 IF VE<>19THEN2600
2410 IFOB=0ANDG1=0THENPRINT"":VE=0:GOTO1130
2415 IFOB=1ANDOO(1)=ZNTHENPRINT"ES IST EINE GROSSE SEEMANNSKISTE."
2416 IFOB=1ANDOO(1)=ZNANDTU=0THENPRINT"SIE IST VERSCHLOSSEN, LAESST"
2417 IFOB=1ANDOO(1)=ZNANDTU=0THENPRINT"SICH ABER OEFFNEN.":GOTO1000
2418 IFOB=1ANDOO(1)=ZNANDTU=1THENPRINT"SIE IST OFFEN";
2419 IFOB=1ANDTU=1ANDOO(1)=ZNANDGE(1)<>-2THENPRINT" UND LEER.":GOTO1000
2420 IFOB=1ANDTU=1ANDOO(1)=ZNANDGE(1)=-2THENGE(1)=ZN:PRINT" UND ES LIEGT GELD DRIN."
2421 IFOB=2THENPRINT"ES IST UNSER TOTER KAPITAEN."
2422 IFOB=2THENPRINT"EINE GRAESSLICHE WUNDE HAT SEINEN"
2423 IFOB=2THENPRINT"KOERPER ENTSTELLT.":IFGE(2)<>-2THEN1000
2424 IFOB=2ANDGE(2)=-2THENPRINT"SEINE TASCHEN SIND MERKWUERDIG AUSGE-"
2425 IFOB=2ANDGE(2)=-2THENPRINT"BEULT: ES IST EINE PISTOLE DRIN!":GE(2)=ZN:GOTO1000
2426 IFOB=3THENPRINT"ES IST EINE EINFACHE KEROSINLAMPE."
2427 IFOB=3ANDLA=0THENPRINT"SIE SCHAUKELT IN DEN BEWEGUNGEN DES"
2428 IFOB=3ANDLA=0THENPRINT"SCHIFFES. LEISE QUIETSCHER DRINGEN"
2429 IFOB=3ANDLA=0THENPRINT"VON IHR AUS DURCH DEN RAUM.":GOTO1000
2430 IFOB=3ANDLA=1ANDGE(3)<>-2THENPRINT"DURCH DEN STURZ IST SIE ERLOSCHEN."
2431 IFOB=3ANDLA=1ANDGE(3)=-2THENPRINT"IN IHRER SCHALE LIEGT EIN SCHLUESSEL,"
2432 IFOB=3ANDLA=1ANDGE(3)=-2THENPRINT"DER ZUR KAMMERTUER PASSEN KOENNTE."
2433 IFOB=3ANDLA=1ANDGE(3)=-2THENGE(3)=ZN:GOTO1000
2434 IFOB=4THENPRINT"ES LAESST SICH IN ALLE RICHTUNGEN"
2435 IFOB=4THENPRINT"BEWEGEN. ABER FALLS SIE ES NOCH NICHT"
2436 IFOB=4THENPRINT"WISSEN SOLLTEN: WIR BEFINDEN UNS ZWAR"
2437 IFOB=4THENPRINT"AUF DEM WASSER, LIEGEN ABER VOR ANKER,"
2438 IFOB=4THENPRINT"SO DASS SIE IHRE SPIELEREIEN RUHIG"
2439 IFOB=4THENPRINT"LASSEN KOENNTEN!":GOTO1000
2440 IFOB=5THENPRINT"ES IST EINE 17-PFUENDER KANONE."
2441 IFOB=5ANDKA=0THENPRINT"UND WAS NOCH BESSER IST: SIE IST GE-"
2442 IFOB=5ANDKA=0THENPRINT"LADEN!":GOTO63500
2443 IFOB=6THENPRINT"ES IST DIE TOILETTE DER MATROSEN,"
2444 IFOB=6THENPRINT"UND...  AAAAAAAAAAHHHHHHHHHHHHHHHHH..."
2445 IFOB=6THENPRINT"ICH KANN DOCH NICHT SCHWIMMEN... GLUCK!"
2446 IFOB=6THEN60000
2447 IFOB=7ANDGE(5)<>-2THENPRINT"DAS SCHAPP IST LEIDER LEHR."
2448 IFOB=7ANDGE(5)<>-2THENPRINT"DA SIE EBEN SELBER DAS MESSER HERAUSGE-"
2449 IFOB=7ANDGE(5)<>-2THENPRINT"NOMMEN HABEN HAETTEN SIE DAS EIGENT-"
2450 IFOB=7ANDGE(5)<>-2THENPRINT"LICH WISSEN MUESSEN!":GOTO1000
2451 IFOB=7ANDGE(5)=-2THENPRINT"SPANNUNG ERFUELLT MICH, ALS ICH DAS"
2452 IFOB=7ANDGE(5)=-2THENPRINT"SCHAPP DES KOCHES OEFFNE... UND:"
2453 IFOB=7ANDGE(5)=-2THENPRINT"ES IST EIN MESSER DRIN!":GE(5)=ZN:GOTO1000
2454 IFOB=8ANDSE=0THENPRINT"DAS BOOT IST AN EINER HAENGEVORRICHTUNG"
2455 IFOB=8ANDSE=0THENPRINT"BEFESTIGT UND SCHWEBT UEBER DEM WASSER.":GOTO1000
2456 IFOB=8ANDSE=1THENPRINT"DAS BOOT DUEMPELT AUF DEM WASSER UND"
2457 IFOB=8ANDSE=1THENPRINT"SCHEINT AUF MICH ZU WARTEN!":GOTO1000
2458 IFOB=9ANDSE=0THENPRINT"DAS SEIL VERBINDET DAS BOOT MIT DER"
2459 IFOB=9ANDSE=0THENPRINT"HAENGEVORRICHTUNG."
2460 IFOB=9ANDSE=0THENPRINT"MAN MUESSTE ES DURCHSCHNEIDEN, UM MIT"
2461 IFOB=9ANDSE=0THENPRINT"DEM BOOT FAHREN ZU KOENNEN."
2462 IFOB=9ANDSE=0ANDGE(5)=-2THENPRINT"ABER WOMIT?":GOTO1000
2463 IFOB=9ANDSE=0ANDGE(5)<>-2THENPRINT"VIELLEICHT WAERE DAS MESSER GEEIGNET?":GOTO1000
2464 IFOB=9ANDSE=1THENPRINT"DIE ENDEN HAENGEN SCHLAPP HERAB, UND"
2465 IFOB=9ANDSE=1THENPRINT"DAS BOOT LIEGT AUF DEM WASSER."
2466 IFOB=9ANDSE=1THENPRINT"DAS HAETTEN SIE ABER WISSEN MUESSEN,"
2467 IFOB=9ANDSE=1THENPRINT"WO SIE ES DOCH SELBER DURCHGESCHNITTEN"
2468 IFOB=9ANDSE=1THENPRINT"HABEN!":GOTO1000
2469 IFOB=10THENPRINT"ES LIEGT VOR ANKER!":GOTO1000
2470 IFOB=11ANDOO(11)=ZNTHENPRINT"SIE KOENNTEN EINEN WEG VERBERGEN,"
2471 IFOB=11ANDOO(11)=ZNTHENPRINT"SO DICHT SIND SIE.":GOTO1000
2472 IFOB=11ANDOO(11)<>ZNTHENPRINT"WELCHE BUESCHE MEINEN SIE? DIE, DIE SIE"
2473 IFOB=11ANDOO(11)<>ZNTHENPRINT"EBEN ABGEHOLZT HABEN?":GOTO1000
2474 IFOB=12OROB=13ANDT1=0THENPRINT"SIE IST FEST VERSCHLOSSEN.":GOTO1000
2475 IFOB=14ANDB=0THENPRINT"ER SCHAUT MICH LUESTERN AN, WENDET"
2476 IFOB=14ANDB=0THENPRINT"SICH DANN ABER UNINTERRESSIERT AB."
2477 IFOB=14ANDB=0THENPRINT"DOCH, WAS JETZT? ER SCHNELLT HERUM,"
2478 IFOB=14ANDB=0THENPRINT"PACKT MICH, AUHHH, MEIN BEIN... AHHHHH!":GOTO60000
2479 IFOB=14ANDB=1THENPRINT"DER BAER IST MIT MEINEM HONIGGLAS BE-"
2480 IFOB=14ANDB=1THENPRINT"SCHAEFTIGT. ALS ICH IHN INTERRESSIERT"
2481 IFOB=14ANDB=1THENPRINT"MUSTERE SCHAUT ER EINMAL KURZ AUF,"
2482 IFOB=14ANDB=1THENPRINT"VERTIEFT SICH DANN ABER WIEDER IN"
2483 IFOB=14ANDB=1THENPRINT"SEINE HONIGSCHLECKEREI.":GOTO1000
2484 IFOB=15THENPRINT"ER SCHEINT VERTEUFELT TIEF ZU SEIN!" :GOTO1000
2485 IFOB=16THENPRINT"ER IST SEHR HOCH ";
2486 IFOB=16ANDGE(17)=25THENPRINT", ABER MAN KANN MIT"
2487 IFOB=16ANDGE(17)=25THENPRINT"DER ANGELEHNTEN LEITER HOCHKOMMEN.":GOTO1000
2488 IFOB=16ANDGE(17)=-1THENPRINT", ABER WENN SIE DIE"
2489 IFOB=16ANDGE(17)=-1THENPRINT"LEITER ANLEHNEN KOMMEN SIE HOCH.":GOTO1000
2490 IFOB=16ANDGE(17)=39THENPRINT"UND ER ERSCHEINT"
2491 IFOB=16ANDGE(17)=39THENPRINT"MIR UNBEZWINGBAR HOCH.":GOTO1000
2492 IFOB=17THENPRINT"DAS U-BOOT IST VOLLKOMMEN AUS METALL.":GOTO1000
2493 IFOB=18OROB=19ANDT2=0THENPRINT"SIE IST VERSCHLOSSEN.":GOTO1000
2494 IFOB=18OROB=19ANDT2=0THENPRINT"SIE IST OFFEN.":GOTO1000
2495 IFOB=20THENPRINT"SIE ZEIGT FOLGENDES AN:"
2496 IFOB=20THENPRINT"TIEFE:0 WETTER:GUT GESCHW.:0":GOTO1000
2497 IFOB=21ANDSA=0THENPRINT"ER IST FEST VERSCHLOSSEN!":GOTO1000
2498 IFOB=21ANDSA=1ANDGE(12)<>-2ANDGE(13)<>-2THENPRINT"ER IST LEER!":GOTO1000
2499 IFOB=21ANDSA=1ANDGE(12)=-2ANDGE(13)=-2THENPRINT"OH! ES BEFINFEN SICH DIE BAU-"
2500 IFOB=21ANDSA=1ANDGE(12)=-2ANDGE(13)=-2THENPRINT"PLAENE DER NAUTILUS UND ETWAS"
2501 IFOB=21ANDSA=1ANDGE(12)=-2ANDGE(13)=-2THENPRINT"WERKZEUG DARIN."
2502 IFOB=21ANDSA=1ANDGE(12)=-2ANDGE(13)=-2THENGE(12)=ZN:GE(13)=ZN:GOTO1000
2503 IFOB=22ANDGE(14)<>-2THENPRINT"ICH HABE ES DOCH EBEN ERST SELBER"
2504 IFOB=22ANDGE(14)<>-2THENPRINT"DURCHWUEHLT UND DAS BUCH GEFUNDEN!":GOTO1000
2505 IFOB=22ANDGE(14)=-2THENPRINT"TREFFER! UNTER DER BETTDECKE HABE"
2506 IFOB=22ANDGE(14)=-2THENPRINT"ICH EIN BUCH GEFUNDEN!":GE(14)=ZN:GOTO1000
2507 IFOB=23THENPRINT"ICH KANN NICHTS BESONDERES ENTDECKEN.":GOTO1000
2508 IFOB=24ANDGE(15)<>-2THENPRINT"ER IST LEER!":GOTO1000
2509 IFOB=24ANDGE(15)=-2THENPRINT"ICH HABE EINEN BEUTEL ENTDECKT!":GE(15)=ZN:GOTO1000
2510 IFOB=25THENPRINT"ALSO, WAS SOLL MAN HIER SCHON SCHOENES"
2511 IFOB=25THENPRINT"ENTDECKEN? ";
2512 IFOB=25ANDGE(17)<>-2THENPRINT"DIE LEITER HAST DU"
2513 IFOB=25ANDGE(17)<>-2THENPRINT"JA SCHON!":GOTO1000
2514 IFOB=25ANDGE(17)=-2THENPRINT"ABER HALT!"
2515 IFOB=25ANDGE(17)=-2THENPRINT"DA STEHT 'NE LEITER IN DER ECKE!":GE(17)=ZN:GOTO1000
2516 IFOB=26THENPRINT"ICH HABE DOCH GESAGT, DAS DING IST HEISS!!!"
2517 IFOB=26THENPRINT"MEINE GANZEN FINGER SIND VERBRANNT!"
2518 IFOB=26THENPRINT"KANNST'E MIR MAL VERRATEN, WIE ICH DIR"
2519 IFOB=26THENPRINT"JETZT NOCH HELFEN SOLL?":GOTO60000
2520 IFVE<0ANDVE<11THEN1100
2521 IFOB=27THENPRINT"DRAN SEIN? SIE HAT VIELE TASTEN,"
2522 IFOB=27THENPRINT"SCHWARZE UND WEISSE, DAS IST ALLES!":GOTO1000
2523 IFOB=28THENPRINT"ICH KANN DIE KRATERWAENDE DEUTLICH"
2524 IFOB=28THENPRINT"ERKENNEN, SONST ABER AUCH NICHTS.":GOTO1000
2525 IFOB=29ANDPB=0THENPRINT"ANSCHEINEND WOLLEN DIE WAS VON UNS..."
2526 IFOB=29ANDPB=0THENPRINT"'ABER IHR KOENNT DOCH NICHT...'"
2527 IFOB=29ANDPB=0THENPRINT"ANSCHEINEND KOENNEN SIE DOCH... AAHHH!!":GOTO60000
2528 IFOB=29ANDPB=1THENPRINT"SIE SEHEN GEMEIN AUS, TUN MIR ABER"
2529 IFOB=29ANDPB=1THENPRINT"NICHTS. ES LEBE DIE BESTECHUNG!":GOTO1000
2530 IFG1=1ANDGE(1)=ZNORGE(1)=-1THENPRINT"ES FUNKELT SCHOEN!":GOTO1000
2531 IFG1=2ANDGE(2)=ZNORGE(2)=-1ANDPI=0THENPRINT"SIE IST GELADEN!":GOTO1000
2532 IFG1=2ANDGE(2)=ZNORGE(2)=-1ANDPI=1THENPRINT"ICH HABE SIE DOCH EBEN ERST"
2533 IFG1=2ANDGE(2)=ZNORGE(2)=-1ANDPI=1THENPRINT"ABGEFEUERT! IHR LAUF RIECHT"
2534 IFG1=2ANDGE(2)=ZNORGE(2)=-1ANDPI=1THENPRINT"SOGAR NOCH NACH PULVER!":GOTO1000
2535 IFG1=3ANDGE(3)=ZNORGE(3)=-1THENPRINT"ES IST KEIN BESONDERER SCHLUESSEL!":GOTO1000
2536 IFG1=4ANDGE(4)=ZNORGE(4)=-1THENPRINT"SIE LAESST SICH BEWEGEN UND MAN"
2537 IFG1=4ANDGE(4)=ZNORGE(4)=-1THENPRINT"KANN MIT IHR SCHNEIDEN!":GOTO1000
2538 IFG1=5ANDGE(5)=ZNORGE(5)=-1THENPRINT"ES IST FAST STUMPF, WUERDE ABER"
2539 IFG1=5ANDGE(5)=ZNORGE(5)=-1THENPRINT"ZUM SCHNEIDEN REICHEN!":GOTO1000
2540 IFG1=6ANDGE(6)=ZNORGE(6)=-1ANDT3=0THENPRINT"MAN KAN DAMIT SCHWEISSEN!!":GOTO1000
2541 IFG1=6ANDGE(6)=ZNORGE(6)=-1ANDT3=1THENPRINT"DAS SCHWEISSGERAET IST LEER!":GOTO1000
2542 IFG1=7ANDGE(7)=ZNORGE(7)=-1THENPRINT"SIE IST NOCH EIN WENIG VOLL ERDE.":GOTO1000
2543 IFG1=8ANDGE(8)=ZNORGE(8)=-1THENPRINT"WOZU BENUTZT MAN WOHL SCHAUFELN?":GOTO1000
2544 IFG1=9ANDGE(9)=ZNORGE(9)=-1ANDD=0THENPRINT"SIE IST ZUSAMMENGEFALTET.":GOTO1000
2545 IFG1=9ANDGE(9)=ZNORGE(9)=-1ANDD=1THENPRINT"SIE LIEGT OFFEN DA. MAN KOENNTE"
2546 IFG1=9ANDGE(9)=ZNOEGE(9)=-1ANDD=1THENPRINT"SIE ALS FALLSCHIRM BENUTZEN!":GOTO1000
2547 IFG1=10ANDGE(10)=ZNORGE(10)=-1THENPRINT"ER DUFTET VERFUEHRERISCH!":GOTO1000
2548 IFG1=11ANDGE(11)=ZNORGE(11)=-1THENPRINT"ES IST EINFACHES PERGAMENT.":GOTO1000
2549 IFG1=12ANDGE(12)=ZNORGE(12)=-1THENPRINT"MAN KOENNTE NACH IHNEN EINE"
2550 IFG1=12ANDGE(12)=ZNORGE(12)=-1THENPRINT"ZWEITE 'NAUTILUS' BAUEN!"
2551 IFG1=12ANDGE(12)=ZNORGE(12)=-1THENPRINT"SIE SIND EINWANDFREIE BEWEISE!!!":GOTO1000
2552 IFG1=13ANDGE(13)=ZNORGE(13)=-1THENPRINT"MANN KOENNTE EINE SCHIFFSSCHRAUBE
2553 IFG1=13ANDGE(13)=ZNORGE(13)=-1THENPRINT"DAMIT ABSCHRAUBEN!":GOTO1000
2554 IFG1=14ANDGE(14)=ZNORGE(14)=-1THENPRINT"ES HAT DEN TITEL WIE MAN EINE"
2555 IFG1=14ANDGE(14)=ZNORGE(14)=-1THENPRINT"SCHIFFSSCHRAUBE ABSCHRAUBT.":GOTO1000
2556 IFG1=15ANDGE(15)=ZNORGE(15)=-1ANDGE(16)<>-3THENPRINT"ER WAERE IDEAL, UM EINE"
2557 IFG1=15ANDGE(15)=ZNORGE(15)=-1ANDGE(16)<>-3THENPRINT"SCHIFFSSCHRAUBE ZU VER-"
2558 IFG1=15ANDGE(15)=ZNORGE(15)=-1ANDGE(16)<>-3THENPRINT"STAUEN!":GOTO1000
2559 IFG1=16ANDGE(16)=ZNORGE(16)=-1ORGE(16)=-3THENPRINT"ES IST EINE GROSSE"
2560 IFG1=16ANDGE(16)=ZNORGE(16)=-1ORGE(16)=-3THENPRINT"SCHIFFSSCHRAUBE.":GOTO1000
2561 IFG1=17ANDGE(17)=ZNORGE(17)=-1THENPRINT"MAN KANN AN IHR HOCHKLETTERN,"
2562 IFG1=17ANDGE(17)=ZNORGE(17)=-1THENPRINT"WENN MANN SIE IRGENDWO ANLEHNT!":GOTO1000
2563 IFG1=18ANDGE(18)=ZNORGE(18)=-1ANDGE(11)<>-2THENPRINT"SIE SIND GRUEN.":GOTO1000
2564 IFG1=18ANDGE(18)=ZNORGE(18)=-1ANDGE(11)=-2THENPRINT"ES LIEGT EIN ZETTEL"
2565 IFG1=18ANDGE(18)=ZNORGE(18)=-1ANDGE(11)=-2THENPRINT"ZWISCHEN DEN BLAETTEN!"
2566 IFG1=18ANDGE(18)=ZNORGE(18)=-1ANDGE(11)=-1THEN1000
2567 IFOB=30OROB=31OROB=32THENPRINT"WAS SOLL DA SCHON BESONDERES DRAN SEIN?":GOTO1000

2600 REM LESEN -------------------------
2605 IFVE<>16THEN2700
2610 IFG1<>11ANDG1<>14THENPRINT"WAAAASSS SOLL ICH LESEN?":GOTO2700
2615 IFG1=11ANDGE(11)=ZNORGE(11)=-1THENPRINT"ES STEHT DRAUF : "CU
2620 IFG1=14ANDGE(14)=ZNORGE(14)=-1THENPRINT"INTERRESSANTE LEKTUERE."
2621 IFG1=14ANDGE(14)=ZNORGE(14)=-1THENPRINT"ICH GLAUBE, JETZT KOENNTE ICH"
2622 IFG1=14ANDGE(14)=ZNORGE(14)=-1THENPRINT"SOGAR SELBER EINE SCHIFFS-"
2623 IFG1=14ANDGE(14)=ZNORGE(14)=-1THENPRINT"SCHRAUBE ABSCHRAUBEN.":BC=1

2700 REM BENUTZE -----------------------
2705 IFVE<>27THEN2800
2710 IFG1<>2ANDG1<>13THENPRINT"ICH GLAUBE, DAS GAEBE WENIG SINN."
2715 IFG1=2ANDPI=1THENPRINT"SIE IST NICHT MEHR GELADEN."
2720 IFG1=2ANDPI=0THENPRINT"PENG! ICH HABE DIE PISTOLE ABGEFEUERT."
2721 IFG1=2ANDPI=0THENPRINT"DIE LAMPE KOMMT VON DER DECKE GE-"
2722 IFG1=2ANDPI=0THENPRINT"STUERZT.":LA=1:PI=1:GOTO1000
2725 IFG1=13ANDZN<>42THENPRINT"WIESO DENN? WESHALB DENN?"
2730 IFG1=13ANDZN=42ANDGE(16)=42ANDSS=0ANDBU=1THENPRINT"GUT. ICH HABE DIE SCHIFFS-"
2731 IFG1=13ANDZN=42ANDGE(16)=42ANDSS=0ANDBU=1THENPRINT"SCHRAUBE ABMONTIERT.":SS=1
2732 IFG1=13ANDZN=42ANDGE(16)=42ANDBU=0THENPRINT"ICH WEISS NICHT, WIE DAS GEHT!"
2733 IFG1=13ANDZN=42ANDGE(16)=42ANDSS=1THENPRINT"WOZU DENN? LAENGST ERLEDIGT!"
2734 IFOB=25ANDZN=39THENPRINT"ETWAS MEHR PRIVATLEBEN KANN ICH"
2735 IFOB=25ANDZN=39THENPRINT"JA WOHL VERLANGEN, ODER?"

2800 REM TOETE -------------------------
2805 IFVE<>44THEN2900
2810 IFOB<>2ANDOB<>14ANDOB<>29THENPRINT"WAS SOLL ICH TOETEN?"
2815 IFOB=2THENPRINT"LEICHENSCHAENDER!"
2820 IFOB=14THENPRINT"DIE IDEE AN SICH WAR JA GANZ GUT, NUR"
2825 IFOB=14THENPRINT"HABEN SIE VERGESSEN, DEN BAEREN ZU"
2830 IFOB=14THENPRINT"FRAGEN, UND DER WAR GANZ UND GAR NICHT"
2835 IFOB=14THENPRINT"MIT DIESER AKTION EINVERSTANDEN!":GOTO60000
2840 IFOB=29THENPRINT"WAS HABEN SIE SICH DABEI WOHL GE-"
2845 IFOB=29THENPRINT"DACHT? EINER GEGEN VIELE. EIN PROFESSOR"
2850 IFOB=29THENPRINT"GEGEN EINE HORDE PIRATEN?"
2855 IFOB=29THENPRINT"JETZT VERRATEN SIE MIR BITTE NOCH, WAS"
2860 IFOB=29THENPRINT"ICH AUF IHREN GRABSTEIN SCHREIBEN"
2865 IFOB=29THENPRINT"SOLL, BEFOR... AAAHHHHHHHHHH.......":GOTO60000

2900 REM SCHIESSE ----------------------
2905 IFVE<>21THEN3000
2910 IFG1<>2ANDOB<>5THENPRINT"WAS SOLL ICH ABFEUERN?"
2915 IFG1=2THEN2715
2920 IFOB=5ANDPB=0THENPRINT"DAS HAETTEN SIE NICHT TUN SOLLEN,"
2925 IFOB=5ANDPB=0THENPRINT"PROFESSOR. DIE PIRATEN HABEN DURCH DEN"
2930 IFOB=5ANDPB=0THENPRINT"SCHUSS GEMERKT, DAS WIR GEFLOHEN SIND!"
2935 IFOB=5ANDPB=0THENPRINT"DA KOMMEN SIE SCHON... AHHHHHH!!!!":GOTO60000
2940 IFOB=5ANDPB=1THENPRINT"DER SCHUSS VERHALLT UNBEACHTET."

3000 REM WIRF --------------------------
3005 IFVE<>45THEN3100
3010 IFG1<>10THEN2306
3015 IFG1=10ANDGE(10)<>-1THENPRINT"WAS SOLL ICH WERFEN?"
3016 IFG1=10ANDGE(10)=-1ANDZN<>27THENPRINT"GUT. UND WAS SOLLTE DAS?"
3017 IFG1=10ANDGE(10)=-1ANDZN<>27THENGE(10)=ZN:TR=TR-1
3018 IFG1=10ANDGE(10)=-3ANDZN=27THENPRINT"NOCHMAL GEHT DAS ABER NICHT!"
3019 IFG1=10ANDGE(10)=-1ANDZN=27THENPRINT"WOW! ALS ICH DEM BAEREN DEN HONIG"
3020 IFG1=10ANDGE(10)=-1ANDZN=27THENPRINT"VOR DIE FUESSE SCHMEISSE, DA HOLT"
3021 IFG1=10ANDGE(10)=-1ANDZN=27THENPRINT"ER SICH DEN POTT UND HAT UNS AUF"
3022 IFG1=10ANDGE(10)=-1ANDZN=27THENPRINT"EINMAL GANZ VERGESSEN. TOLL!!!!!":TR=TR-1
3023 IFG1=10ANDGE(10)=-1ANDZN=27THENGE(10)=-3:B=1:GE(6)=ZN

3100 REM ESSE --------------------------
3105 IFVE<>47THEN3200
3110 IFG1<>10ANDG1<>4ANDG1<>18ANDG1<>5THENPRINT"DAS WAR JA WOHL DIE BESCHEUERTSTE"
3111 IFG1<>10ANDG1<>4ANDG1<>5THENPRINT"IDEE, DIE SIE JE HATTEN, PROGESSOR!"
3112 IFG1=10ANDGE(10)=-1THENPRINT"MJAMM, SCHMECKT NICHT SCHLECHT, ABER"
3113 IFG1=10ANDGE(10)=-1THENPRINT"ICH GLAUBE, DAS ZEUG HATTE BESTIMMT"
3114 IFG1=10ANDGE(10)=-1THENPRINT"'NEN ANDEREN ANWENDUNGSBEREICH!":GE(10)=99
3115 IFG1=10ANDGE(10)=-3THENPRINT"DEN HABEN SIE DOCH SCHON DEM"
3116 IFG1=10ANDGE(10)=-3THENPRINT"BAEREN VERABREICHT..."
3117 IFG1=10ANDGE(10)=-2THENPRINT"WAS SOLL ICH ESSEN?"
3118 IFG1=4ANDGE(4)=-2THENPRINT"WAS SOLL ICH ESSEN?"
3119 IFG1=4ANDGE(4)=-1THENPRINT"AHHHHHH ICH BIN DOCH KEIN SCHWERT-"
3120 IFG1=4ANDGE(4)=-1THENPRINT"SCHLUCKER!":GOTO60000
3121 IFG1=4ANDGE(4)>0ANDGE(4)<44THENPRINT"DIE HABE ICH ABER NICHT BEI MIR!"
3122 IFG1=5THENG1=4:GOTO3118
3123 IFG1=18ANDGE(11)<>-2THENPRINT"ICH BIN DOCH KEIN VEGETARIER!"
3124 IFG1=18ANDGE(11)=-2THENPRINT"ICH ES DAS ZEUG ZWAR NICHT, DOCH ALS"
3125 IFG1=18ANDGE(11)=-2THENPRINT"ICH ES UNTERSUCHE KOMMT EIN ZETTEL"
3126 IFG1=18ANDGE(11)=-2THENPRINT"ZUM VORSCHEIN!":GE(11)=ZN

3200 REM ENTFALTE ----------------------
3205 IFVE<>55THEN3300
3210 IFG1<>9THENPRINT"WOZU SOLL DAS GUT SEIN?"
3215 IFG1=9ANDD=1THENPRINT"IST SIE DOCH SCHON LAENGST!"
3216 IFG1=9ANDD=0THENPRINT"OK. SIE IST NUN ENTFALTET.":D=1

3300 REM GRABE -------------------------
3305 IFVE<>58THEN3400
3310 IFGE(8)<>-1THENPRINT"WOMIT DENN, SIE SCHLAUBERGER?"
3315 IFZN<>23ANDGE(8)=-1THENPRINT"OK. ABER WOZU DENN?"
3316 IFZN=23ANDGE(8)=-1ANDGE(7)<>-2THENPRINT"HIER HABE ICH DOCH SCHON GEGRABEN!"
3317 IFZN=23ANDGE(8)=-1ANDGE(7)=-2THENPRINT"OH, ICH HABE EINE AXT GEFUNDEN!"
3318 IFZN=23ANDGE(8)=-1ANDGE(7)=-2THENPRINT"SIE MUSS SCHON LANGE HIER LIEGEN,"
3319 IFZN=23ANDGE(8)=-1ANDGE(7)=-2THENPRINT"DENN SIE IST VOLLER ERDE UND"
3320 IFZN=23ANDGE(8)=-1ANDGE(7)=-2THENPRINT"TOTAL VERDRECKT!":GE(7)=ZN

3400 REM SAVE --------------------------
3405 IFVE<>63THEN3500
3410 PRINT"";:INPUT"FILENAME";FI$
3415 SYS65511
3416 PRINT"BITTE DISKETTEN-SEITE 2 EINLEGEN."
3417 GETA$:IFA$=""THEN3417
3420 OPEN1,8,15,"I":OPEN2,8,2,"#":PRINT#1,"M-R"CHR$(144)CHR$(7)CHR$(16)
3421 INPUT#1,A$:CLOSE2:CLOSE1
3422 IFA$<>"* 20000 SIDE 2 *"THENPRINT"FALSCHE DISKETTE!":GOTO3416
3425 OPEN1,8,15,"I":PRINT#1,"M-R"CHR$(250)CHR$(2)CHR$(3)
3426 GET#1,A$,B$,B$:A=ASC(A$+CHR$(0))+256*ASC(B$+CHR$(0)):CLOSE1
3427 IFA<2THEN63000
3428 SYS65511
3429 OPEN2,8,2,FI$+",P,W"
3430 PRINT#2,ZN:PRINT#2,TU:PRINT#2,PI:PRINT#2,LA:PRINT#2,SE:PRINT#2,B:PRINT#2,BU
3431 PRINT#2,T1:PRINT#2,T2:PRINT#2,T3:PRINT#2,SA:PRINT#2,BC:PRINT#2,BE
3432 PRINT#2,D:PRINT#2,TR:PRINT#2,KA:PRINT#2,PB:PRINT#2,CU:PRINT#2,SS
3433 FORI=1TOOZ:PRINT#2,OO(I):NEXT
3434 FORI=1TOGZ:PRINT#2,GE(I):NEXT
3435 CLOSE2
3436 VE=0:GOTO1130

3500 REM LOAD --------------------------
3505 IFVE<>65THEN3600
3507 SYS65511
3510 PRINT"";:INPUT"FILENAME";FI$
3515 PRINT"BITTE DISKETTEN-SEITE 2 EINLEGEN."
3516 GETA$:IFA$=""THEN3516
3520 OPEN1,8,15,"I":OPEN2,8,2,"#":PRINT#1,"M-R"CHR$(144)CHR$(7)CHR$(16)
3521 INPUT#1,A$:CLOSE2:CLOSE1
3522 IFA$<>"* 20000 SIDE 2 *"THENPRINT"FALSCHE DISKETTE!":GOTO3416
3528 SYS65511
3529 OPEN2,8,2,FI$+",P,R"
3530 INPUT#2,ZN:INPUT#2,TU:INPUT#2,PI:INPUT#2,LA:INPUT#2,SE:INPUT#2,B:INPUT#2,BU
3531 INPUT#2,T1:INPUT#2,T2:INPUT#2,T3:INPUT#2,SA:INPUT#2,BC:INPUT#2,BE
3532 INPUT#2,D:INPUT#2,TR:INPUT#2,KA:INPUT#2,PB:INPUT#2,CU:INPUT#2,SS
3533 FORI=1TOOZ:INPUT#2,OO(I):NEXT
3534 FORI=1TOGZ:INPUT#2,GE(I):NEXT
3535 CLOSE2
3536 VE=0:GOTO1130

3600 REM HILFE -------------------------
3605 IFVE<>67THEN3700
3610 IFZN=1ANDPI=0ANDGE(2)<>-2THENPRINT"WOZU SIND PISTOLEN DENN DA?":GOTO1000
3620 IFZN=10ANDSE=0THENPRINT"SEILE MUSS MAN DURCHSCHNEIDEN!":GOTO1000
3625 IFZN=22ANDPI=0THENPRINT"PIRATEN SIND GELDGIERIG!":GOTO1000
3630 IFZN=27ANDGE(10)<>-3THENPRINT"BAEREN ESSEN HONIG!":GOTO1000
3635 IFZN=26ANDGE(18)=-2THENPRINT"BLAETTER KOENNEN BLAETTER VERBERGEN!":GOTO1000
3640 IFZN=25ANDGE(17)=-2THENPRINT"WOMIT KLETTERT MAN AUF BAEUME?":GOTO1000
3645 IFZN=42ANDSS=0THENPRINT"EINE SCHIFFSSCHRAUBE WAERE EIN BEWEIS!":GOTO1000
3650 PRINT"DU DENKST NICHT, ALSO BIST DU NICHT!"


3700 REM AUFRUF DER SPEZ. ACTION -------
3710 GOSUB10000+ZN*100+20
3800 GOTO1000

10000 REM SPIELKARTE -------------------

10100 REM 1
10102 DATA 0,0,0,0,0,0,0,0,0,0
10105 PRINT"ICH BIN MICH IN DER KAPITAENSKAJUETE."
10106 PRINT"IN EINER ECKE LIEGT DER TOTE KAPITAEN."
10107 PRINT"EINE TRUHE STEHT IM RAUM";
10108 IFLA=0THENPRINT" UND EINE"
10109 IFLA=0THENPRINT"LAMPE SCHAUKELT IN DEN"
10110 IFLA=0THENPRINT"RHYTHMISCHEN BEWEGUNGEN DES SCHIFFES."
10111 IFLA=1THENPRINT" UND EINE LAMPE"
10112 IFLA=1THENPRINT"LIEGT AUF DEM BODEN."
10113 IFLA=1THENPRINT"PULVERDAMPF VERNEBELT DEN RAUM."
10120 IFT1=1THENRI(4)=2
10121 IFVE=23ANDOB=32ANDGE(3)<>-1THENPRINT"WIE DENN?"
10122 IFVE=23ANDOB=32ANDT1=1THENPRINT"WIESO DENN NOCHMAL?"
10125 IFVE=23ANDOB=32ANDGE(3)=-1ANDT1=0THENPRINT"OK.":T1=1:RI(4)=2:GE(3)=-3:TR=TR-1
10126 IFVE=23ANDOB=1ANDTU=1THENPRINT"SIE IST LAENGST OFFEN!!!"
10127 IFVE=23ANDOB=1ANDTU=0THENPRINT"KNIRSCHEND OEFFNET SICH DER SCHWERE"
10128 IFVE=23ANDOB=1ANDTU=0THENPRINT"TRUHENDECKEL UND SCHLAEGT ZURUECK."
10129 IFVE=23ANDOB=1ANDTU=0THENTU=1
10130 IFVE=31ANDOB=32ANDT1=1THENVE=4:GOTO1100
10140 IFVE=31ANDOB=32ANDT1=0THENPRINT"BUMS! AUA MEIN KOPF!"
10150 RETURN

10200 REM 2
10202 DATA 0,4,1,3,0,5,0,0,0,0
10205 PRINT"ICH BIN AUF DEM ACHTERDECK UNSERES"
10206 PRINT"DAMPF UND SEGELSCHIFFES."
10207 PRINT"EIN UNBEMANNTES STEUERRAD BEWEGT"
10208 PRINT"SICH IM WIND."
10220 IFVE=23ANDOB=32THENPRINT"SIE IST DOCH SCHON OFFEN!"
10250 RETURN

10300 REM 3
10302 DATA 0,5,2,0,4,0,0,0,0,0
10305 PRINT"ICH BIN AUF DEM ACHTERDECK UNSERES"
10306 PRINT"DAMPF UND SEGELSCHIFFES."
10320 IFVE=23ANDOB=32ANDGE(3)<>-1THENPRINT"WOMIT DENN?"
10330 IFVE=23ANDOB=32ANDGE(3)=-1THENPRINT"              GRATULIERE !"
10331 IFVE=23ANDOB=32ANDGE(3)=-1THEN62000
10340 RETURN

10400 REM 4
10402 DATA 2,6,0,5,0,0,0,3,0,0
10405 PRINT"ICH BIN AUF DEM QUARTERDECK UNSERES"
10406 PRINT"SCHIFFES."
10420 RETURN

10500 REM 5
10502 DATA 3,0,4,0,6,0,2,0,0,0
10505 PRINT"ICH BIN AUF DEM QUARTERDECK UNSERES"
10506 PRINT"SCHIFFES. EINE KANONE STEHT AUF DEN"
10507 PRINT"PLANKEN ALS WARTE SIE DARAUF, ABGE-"
10508 PRINT"FEUERT ZU WERDEN."
10520 IFVE=30ANDOB=5THENPRINT"WIE DENN? ICH BIN KEIN KANONIER"
10521 IFVE=30ANDOB=5THENPRINT"SONDERN PROFESSOR!"
10530 RETURN

10600 REM 6
10602 DATA 4,9,8,7,0,0,0,5,0,0
10605 PRINT"ICH BIN AUF DER BACK UNSERES SCHIIFES."
10620 RETURN

10700 REM 7
10702 DATA 0,0,6,0,0,0,0,0,0,0
10705 PRINT"ICH BIN IM REICHE UNSERES KOCHS, DER"
10706 PRINT"KOMBUESE. DIE TYPISCHEN GERAEUSCHE VON"
10707 PRINT"SICH BEWEGENDEN TOEPFEN UND PFANNEN"
10708 PRINT"EMPFANGEN MICH. AN DER WAND HAENGT EIN"
10709 PRINT"OFFENES SCHAPP, EIN SCHRANKAEHNLICHER"
10710 PRINT"GEGENSTAND."
10720 IFVE=23ANDOB=7THENPRINT"ES IST DOCH SCHON OFFEN, PROFESSOR!":GOTO1000
10730 RETURN

10800 REM 8
10802 DATA 0,0,0,6,0,0,0,0,0,0
10805 PRINT"ICH BIN AUF DER BACK UNSERES SCHIFFES."
10806 PRINT"VOR MIR IST DIE GALION, DER ABTRITT"
10807 PRINT"(TOILETTE) DER SEELEUTE."
10820 IFVE=31ANDOB=6THEN2443
10830 RETURN

10900 REM 9
10902 DATA 6,0,0,10,0,0,0,0,0,0
10905 PRINT"ICH BIN AUF DER KUHL UNSERES SCHIFFES."
10906 IFSE=0THENPRINT"AN DEN HAENGEVORRICHTUNGEN HAENGT UNSER"
10907 IFSE=0THENPRINT"BEIBOOT. ES LAEDT ZUM MITFAHTEN EIN."
10908 IFSE=1THENPRINT"UNTER MIR, NEBEN DER BORDWAND SCHAUKELT"
10909 IFSE=1THENPRINT"DAS BEIBOOT AUF DEN WELLEN."
10920 IFSE=1THENRI(4)=11
10921 IFVE=31ANDOB=8THENVE=4:GOTO1100
10930 RETURN

11000 REM 10
11002 DATA 0,0,9,0,0,0,0,0,0,0
11005 PRINT"ICH BIN IM BEIBOOT UNSERES SCHIFFES."
11006 IFSE=0THENPRINT"MITSAMT DEM BOOT HAENGE ICH NOCH AN DER"
11007 IFSE=0THENPRINT"HAENGEVORRICHTUNG UND WERDE DURCH EIN"
11008 IFSE=0THENPRINT"SEIL GEHALTEN."
11009 IFSE=1THENPRINT"ES SCHAUKELT AUF DEN WELLEN. RINGS UM"
11010 IFSE=1THENPRINT"IST NUR UNSER SCHIFF, DER OZEAN UND"
11011 IFSE=1THENPRINT"DIE KLEINE INSEL ZU SEHEN."
11020 IFVE<>38THEN11030
11021 IFSE=1THENPRINT"HABE ICH DOCH SCHON LAENGST!"
11022 IFGE(5)<>-1ANDSE=0THENPRINT"WOMIT DENN BITTE SCHOEN?"
11023 IFGE(5)=-1ANDSE=0THENPRINT"OK."
11024 IFGE(5)=-1ANDSE=0THENPRINT"MIT LAUTEM PLATSCHEN FAELLT DAS"
11025 IFGE(5)=-1ANDSE=0THENPRINT"BEIBOOT MIT MIR INS WASSER.":ZN=11:SE=1:GOTO1000
11030 RETURN

11100 REM 11
11102 DATA 0,13,0,12,0,14,0,0,0,0
11105 PRINT"ICH BIN IN UNSEREM BEIBOOT."
11106 PRINT"DIE RUDER LADEN ZUM LOSFAHREN EIN."
11107 PRINT"NEBEN MIR IST UNSER SCHIFF ZU SEHEN UND"
11108 PRINT"ETWAS WEITER ENTFERNT SEHE ICH DIE"
11109 PRINT"KLEINE INSEL."
11120 IFVE=31ANDOB=10THENZN=9:GOTO1130
11125 RETURN

11200 REM 12
11202 DATA 0,14,11,15,13,16,0,0,0,0
11205 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11220 RETURN

11300 REM 13
11302 DATA 11,17,15,14,15,18,15,12,0,0
11305 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11320 RETURN

11400 REM 14
11402 DATA 12,18,13,16,17,0,11,15,0,0
11405 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11420 RETURN

11500 REM 15
11502 DATA 0,16,12,13,14,13,0,0,0,0
11505 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11520 RETURN

11600 REM 16
11602 DATA 15,19,14,12,18,0,12,12,0,0
11605 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11620 RETURN

11700 REM 17
11702 DATA 13,14,12,18,15,14,16,14,0,0
11705 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11720 RETURN

11800 REM 18
11802 DATA 14,16,17,0,13,0,13,16,0,0
11805 PRINT"ICH BEFINDE MICH AUF DEM FREIEN OZEAN."
11820 RETURN

11900 REM 19
11902 DATA 16,20,0,0,0,0,0,0,0,0
11905 PRINT"ICH BIN AUF DEM SANDSTRAND DER KLEINEN"
11906 PRINT"INSEL. IHR VULKANISCHER URSPRUNG"
11907 PRINT"OFFENBART SICH MIR AN VIELEN KLEINIG-"
11908 PRINT"KEITEN."
11920 RETURN

12000 REM 20
12002 DATA 19,23,27,0,28,0,0,0,0,0
12005 PRINT"ICH BIN AUF EINEM KLEINEN TRAMPELPFAD,"
12006 PRINT"DEN DIE TIERE, DIE DIESE INSEL BE-"
12007 PRINT"WOHNEN WOHL IN LANGER ZEIT FEST-"
12008 PRINT"GETRAMPELT HABEN MUESSEN."
12009 IFBU=1THENRI(4)=21
12020 IFVE=38ANDOB=11ANDBU=1THENPRINT"WELCHE BUESCHE DENN?"
12021 IFVE=38ANDOB=11ANDBU=0ANDGE(4)<>-1THENPRINT"WOMIT DENN, PROFESSOR?"
12022 IFVE=38ANDOB=11ANDBU=0ANDGE(4)=-1THENPRINT"OK. SEHN SIE MAL HER!":BU=1:OO(11)=-2
12025 RETURN

12100 REM 21
12102 DATA 0,0,20,0,0,0,0,0,0,0
12105 PRINT"ICH STEHE VOR EINER HUETTE, DEREN TUER"
12106 IFT2=0THENPRINT"FEST VERSCHLOSSEN IST."
12107 IFT2=1THENPRINT"SPERRANGELWEIT OFFEN STEHT."
12108 PRINT"AUS DEM INNEREN DRINGT DER LAERM VON"
12109 PRINT"GROELENDEN PIRATEN HEREIN."
12110 PRINT"HIERHER HABEN SIE SICH ALSO"
12111 PRINT"GEFLUECHTET. VORSICHT IST ALSO"
12112 PRINT"ANGEBRACHT."
12120 IFT2=1THENRI(4)=22
12121 IFVE=23ORVE=49ANDGE(7)<>-1THENPRINT"WIE DENN?"
12122 IFVE=23ORVE=49ANDT2=1THENPRINT"WESHALB DENN NOCHMAL? KRAFTVERSCHWENDUNG!"
12125 IFVE=23ORVE=49ANDGE(7)=-1ANDT2=0THENPRINT"OK.":T2=1:RI(4)=22:GOTO12150
12150 RETURN

12200 REM 22
12202 DATA 0,0,21,0,0,0,0,0,0,0
12205 PRINT"ICH BIN IN DER HUETTE DER PIRATEN."
12206 PRINT"WENN ICH MICH SO UMSCHAUE, DANN MEINE"
12207 PRINT"ICH, MEIN LETZTES STUENDLEIN HABE"
12208 PRINT"GESCHLAGEN. ICH BEZWEIFLE, DASS ICH"
12209 PRINT"DIESER WILDEN HORDE ENTWISCHEN KANN."
12210 PRINT"JEDER EINZELNE SCHAUT SO AUS, ALS"
12211 PRINT"WUERDE ER SEINE GROSSMUTTER IM SCHLAF"
12212 PRINT"ERSTECHEN UM IHR EIN PAAR CENTS ZU"
12213 PRINT"KLAUEN."
12220 IFVE=53ANDOB=29ANDGE(1)<>-1THENPRINT"DAS WAR WOHL EIN SCHLAG INS WASSER!"
12221 IFVE=53ANDOB=29ANDGE(1)<>-1THENPRINT"ALS DIE PIRATEN ENTDECKEN, DAS WIR"
12222 IFVE=53ANDOB=29ANDGE(1)<>-1THENPRINT"GAR NICHTS ZUM BESTECHEN HABEN, DA"
12223 IFVE=53ANDOB=29ANDGE(1)<>-1THENPRINT"GINGS UNS ABER WIRKLICH SCHLECHT!!"
12224 IFVE=53ANDOB=29ANDGE(1)<>-1THEN60000
12225 IFVE=53ANDOB=29ANDGE(1)=-1THENPRINT"SCHWEIN GEHABT. ALS WIR IHNEN"
12226 IFVE=53ANDOB=29ANDGE(1)=-1THENPRINT"DAS GELD GEBEN, DA GEBEN SIE UNS"
12227 IFVE=53ANDOB=29ANDGE(1)=-1THENPRINT"DEN SCHLUESSEL, DEN WIR BRAUCHEN,"
12228 IFVE=53ANDOB=29ANDGE(1)=-1THENPRINT"UM DIE MANNSCHAFT ZU BEFREIEN!":GE(3)=-1
12230 IFVE=51ANDG1=1ANDGE(1)<>-1THENPRINT"DAS WAR WOHL EIN SCHLAG INS WASSER!"
12231 IFVE=53ANDG1=1ANDGE(1)<>-1THENPRINT"ALS DIE PIRATEN ENTDECKEN, DAS WIR"
12232 IFVE=53ANDG1=1ANDGE(1)<>-1THENPRINT"GAR NICHTS ZUM BESTECHEN HABEN, DA"
12233 IFVE=53ANDG1=1ANDGE(1)<>-1THENPRINT"GINGS UNS ABER WIRKLICH SCHLECHT!!"
12234 IFVE=53ANDG1=1ANDGE(1)<>-1THEN60000
12235 IFVE=53ANDG1=1ANDGE(1)=-1THENPRINT"SCHWEIN GEHABT. ALS WIR IHNEN"
12236 IFVE=53ANDG1=1ANDGE(1)=-1THENPRINT"DAS GELD GEBEN, DA GEBEN SIE UNS"
12237 IFVE=53ANDG1=1ANDGE(1)=-1THENPRINT"DEN SCHLUESSEL, DEN WIR BRAUCHEN,"
12238 IFVE=53ANDG1=1ANDGE(1)=-1THENPRINT"UM DIE MANNSCHAFT ZU BEFREIEN!":GE(3)=
12240 RETURN

12300 REM 23
12302 DATA 20,25,0,24,0,0,0,0,0,0
12305 PRINT"ICH STEHE VOR EINER UNVERSCHLOSSENEN"
12306 PRINT"HUETTE, DIE VON BAEUMEN UNGEBEN IST."
12307 PRINT"DER ERDBODEN IST HIER LOCKERER ALS"
12308 PRINT"AN ANDEREN STELLEN DER INSEL. IDEAL"
12309 PRINT"UM ETWAS ZU VERGRABEN ODER UM ETWAS"
12310 PRINT"ANZUBAUEN, ETWA KARTOFFELN ODER SO."
12320 RETURN

12400 REM 24
12402 DATA 0,0,23,0,0,0,0,0,0,0
12405 PRINT"ICH BIN IN DER HUETTE. SIE IST VOLL-"
12406 PRINT"GESTOPFT MIT GERUEMPEL, SCHEINT ABER"
12407 PRINT"SCHON SEIT ETLICHEN JAHREN NICHT MEHR"
12408 PRINT"BETRETEN WORDEN ZU SEIN."
12420 RETURN

12500 REM 25
12502 DATA 23,0,0,0,0,0,0,0,0,0
12505 PRINT"ICH BIN AUF EINER WIESE, AUF DER MITTEN"
12506 PRINT"IN DER EINSAMKEIT EIN HOHER BAUM STEHT."
12507 PRINT"ZUM KLETTERN SCHEINT ER MIR ABER ZU"
12508 PRINT"HOCH ZU SEIN."
12520 IFVE=31ANDOB=16ORG1=17ANDGE(17)<>ZNTHENPRINT"ICH RUTSCHE ABER IMMER AB!":GOTO12530
12521 IFVE=31ANDOB=16ORG1=17ANDGE(17)=-1THENPRINT"LEHNEN SIE DOCH ERST DIE"
12522 IFVE=31ANDOB=16ORG1=17ANDGE(17)=-1THENPRINT"LEITER AN DEN BAUM. JA?!?":GOTO12530
12523 IFVE=31ANDOB=16ORG1=17ANDGE(17)=ZNTHENZN=26:GOTO1130
12530 RETURN

12600 REM 26
12602 DATA 0,0,0,0,0,0,0,0,0,25
12605 PRINT"ICH BIN AUF DEM BAUM."
12606 PRINT"DAS GEAEST IST SEHR DICHT, UND DIE"
12607 PRINT"EINZELNEN BLAETTER SEHEN AUS WIE"
12608 PRINT"ZETTEL."
12620 RETURN

12700 REM 27
12702 DATA 0,0,0,20,0,0,0,0,0,0
12705 PRINT"ICH BIN IN EINER DUNKLEN HOEHLE, DIE"
12706 PRINT"JEDOCH, WIE ES SCHEINT, NUR EINEN RAUM"
12707 PRINT"ZU HABEN SCHEINT."
12708 IFB=0THENPRINT"IN DER ECKE STEHT EIN BAER UND SCHEINT"
12709 IFB=0THENPRINT"NICHT VIEL FEDERLESENS MIT MIR MACHEN"
12710 IFB=0THENPRINT"ZU WOLLEN, SO FLETSCHT ER DIE ZAEHNE."
12711 IFB=1THENPRINT"IN DER ECKE IST EIN BAER, DER MIT EINEM"
12712 IFB=1THENPRINT"GLAS HONIG BESCHAEFTIGT IST. ER "
12713 IFB=1THENPRINT"SCHENKT MIR KEINE WEITERE BEACHTUNG"
12714 IFB=1THENPRINT"MEHR NACHDEM ER MICH EINMAL UN-"
12715 IFB=1THENPRINT"INTERRESSIERT GEMUSTERT HAT."
12720 RETURN

12800 REM 28
12802 DATA 0,0,0,0,0,0,0,20,0,0
12805 PRINT"ICH STEHE AM RANDE EINES KRATERS."
12806 PRINT"IM EINFALLENDEN SONNENLICHT GLAENZT"
12807 PRINT"ETWAS METALLISCHES AUF DEM BODEN."
12808 PRINT"ES SCHEINT JEDOCH SEHR TIEF NACH UNTEN"
12809 PRINT"ZU GEHEN."
12820 IFVE=31ORVE=57ANDOB=15ANDD=0THENPRINT"AAAAAAAAAAHHHHHHHH... BUMM."
12821 IFVE=31ORVE=57ANDOB=15ANDD=0THENPRINT"DAS WAR ZU HOCH!":GOTO60000
12825 IFVE=31ORVE=57ANDOB=15ANDD=1THENPRINT"OK.":FORI=1TO2000:NEXT:ZN=29:GOTO1130
12830 RETURN

12900 REM 29
12902 DATA 0,30,0,0,0,0,0,0,28,0
12905 PRINT"ICH BIN AUF DEM BODEN DES KRATERS"
12906 PRINT"UND IN MEINER NAEHE STEHT DAS U-BOOT"
12907 PRINT"'NAUTILUS'. WIE MAN VON OBEN NICHT"
12908 PRINT"SEHEN KANN, SO SIND STEIGEISEN AN DEN"
12909 PRINT"WAENDEN ANGEBRACHT."
12920 IFT3=1THENRI(2)=30
12925 IFVE=23ANDGE(6)=-1ANDT3=0THENPRINT"OK.":T3=1:RI(2)=30:GOTO12940
12940 RETURN

13000 REM 30
13002 DATA 29,0,0,0,0,0,0,0,0,0
13005 PRINT"ICH STEHE VOR DEM MONSTROESEN AUFBAU"
13006 PRINT"DER NAUTILUS. ALS ICH MICH VOR ZWEI"
13007 PRINT"JAHREN IN DEM METALLKASTEN BEFAND, DA"
13008 PRINT"KAM SEINE IMPONANZ NUR VAGE ZUM"
13009 PRINT"AUSDRUCK."
13010 IFT3=0THENPRINT"EINE EISERNE TUER VERSPERRT DEN ZUGANG"
13011 IFT3=0THENPRINT"ZUM INNEREN DES SCHIFFES."
13012 IFT3=1THENPRINT"EINE AUFGESCHWEISSTE TUER GEWAEHRT"
13013 IFT3=1THENPRINT"EINLASS IN DAS INNERE DES SCHIFFES."
13019 IFT3=1THENRI(4)=31
13020 IFVE=23ANDOB=32ANDGE(6)<>-1THENPRINT"DAS GEHT LEIDER NICHT!"
13021 IFVE=23ANDOB=32ANDT3=1THENPRINT"SIE IST DOCH SCHON AUFGESCHWEISST!"
13022 IFVE=23ANDOB=32ANDGE(6)=-1ANDT3=0THENPRINT"OK."
13023 IFVE=23ANDOB=32ANDGE(6)=-1ANDT3=0THENPRINT"ICH SCHWEISSE DIE TUER AUF!"
13024 IFVE=23ANDOB=32ANDGE(6)=-1ANDT3=0THENRI(4)=31:T3=1
13030 RETURN

13100 REM 31
13102 DATA 0,33,30,32,0,0,0,0,0,0
13105 PRINT"ICH BIN IM MASCHINENRAUM DES U-BOOTES."
13106 PRINT"ES IST DER VORHOF ZU DER GANZEN PRACHT"
13107 PRINT"DER INNENEINRICHTUNG DES U-BOOTES."
13108 PRINT"HIER MUSS JEDER DURCH, DER INS INNERE"
13109 PRINT"WEITER VORSTOSSEN MOECHTE."
13110 PRINT"AN DER WAND HAENGT EINE ANZEIGENTAFEL,"
13111 PRINT"AN DER MAN DINGE WIE WETTER, TIEFE UND"
13112 PRINT"GESCHWINDIGKEIT ABLESEN KANN."
13120 RETURN

13200 REM 32
13202 DATA 0,34,31,35,33,0,0,0,0,0
13205 PRINT"ICH BIN IN EINEM GANG, DER VON"
13206 PRINT"STAEHLERNEN WAENDEN UMRINGT IST."
13220 RETURN

13300 REM 33
13302 DATA 31,37,0,0,0,32,0,0,0,0
13305 PRINT"ICH BIN IN EINEM GANG, DER VON"
13306 PRINT"STAEHLERNEN WAENDEN UMRINGT IST."
13320 RETURN

13400 REM 34
13402 DATA 32,0,0,0,0,39,0,0,0,0
13405 PRINT"ICH BIN IN DER KAPITAENSKAJUETE."
13406 PRINT"HIER HAT FRUEHER KAPITAEN NEMO GEHAUST."
13407 IFSA=0THENPRINT"IN EINER ECKE STEHT EIN FEST VER-"
13408 IFSA=0THENPRINT"SCHLOSSENER KOMBINATIONSSAFE."
13409 IFSA=1THENPRINT"IN EINER ECKE STEHT EIN SAFE, DESSEN"
13410 IFSA=1THENPRINT"TUER VOM LUFTZUG BEWEGT WIRD."
13420 IFVE=23ANDSA=1THENPRINT"ER IST SCHON OFFEN, PROFESSOR!!!!!!"
13421 IFVE=23ANDSA=0THEN62500

13422 RETURN
13500 REM 35
13502 DATA 0,36,32,0,0,0,0,0,0,0
13505 PRINT"ICH BIN IN EINEM GANG, DER VON"
13506 PRINT"STAEHLERNEN WAENDEN UMRINGT IST."
13520 RETURN
13600 REM 36
13602 DATA 35,39,0,0,0,0,0,0,0,0

13605 PRINT"ICH BIN IN DER KAJUETE EINES MATROSEN."
13606 PRINT"EIN ROSTIGES BETTGESTELL, DAS BEI JEDER"
13620 RETURN

13700 REM 37
13702 DATA 33,40,0,38,0,0,0,0,0,0
13705 PRINT"ICH BIN IN EINEM GANG, DER VON"
13706 PRINT"STAEHLERNEN WAENDEN UMRINGT IST."
13720 RETURN

13800 REM 38
13802 DATA 0,0,37,39,0,0,0,0,0,0
13805 PRINT"ICH BIN IN DER KAJUETE, IN DER ICH MICH"
13806 PRINT"AUCH AUF MEINER FAHRT AUF DER NAUTILUS"
13807 PRINT"AUFGEHALTEN HABE."
13820 IFVE=23ANDOB=24THENPRINT"WOZU DENN? DER SCHRANK IST SCHON OFFEN."
13825 RETURN

13900 REM 39
13902 DATA 36,0,38,0,0,0,34,0,0,0
13905 PRINT"ICH BIN AUF DER TOILETTE."
13906 PRINT"DER RAUM HAT ZUGANG ZU JEDER ANGREN-"
13907 PRINT"ZENDEN KAJUETE."
13920 IFVE=31ANDOB=39THEN2734
13940 RETURN

14000 REM 40
14002 DATA 37,42,0,41,0,43,0,0,0,0
14005 PRINT"ICH BIN IN EINEM GANG, DER VON"
14006 PRINT"STAEHLERNEN WAENDEN UMRINGT IST."
14020 RETURN

14100 REM 41
14102 DATA 0,0,40,0,0,0,0,0,0,0
14105 PRINT"ICH BIN IM ELEKTRIZITAETSRAUM."
14106 PRINT"HIER WURDE DIE ENERGIE FUER DIE"
14107 PRINT"NAUTILUS HERGESTELLT. KOMISCH, ES"
14108 PRINT"FAELLT AUF, DAS DER KESSEL IMMER NOCH"
14109 PRINT"IN FUNKTION IST UND EINE ENORME HITZE"
14110 PRINT"AUSSTRAHLT. SCHWEISTROPFEN TRETEN MIR"
14111 PRINT"AUF DIE STIRN UND LAUFEN MIR DIE"
14112 PRINT"WANGEN HINAB."
14120 RETURN

14200 REM 42
14202 DATA 40,0,0,0,0,0,0,0,0,0
14205 PRINT"ICH BIN AUF DER AEUSSEREN PLATTFORM."
14206 PRINT"UNTER MIR LIEGT DIE SCHIFFSSCHRAUBE,"
14207 PRINT"DIE NUR MIT EINIGEN SCHRAUBEN AM SCHIFF"
14208 PRINT"BEFESTIGT IST."
14220 IFVE=38ANDSS=0THENPRINT"WESHALB DENN?"
14221 IFVE=38ANDGE(13)<>-1THENPRINT"WOMIT SOLL ICH DAS DENN MACHEN?"
14222 IFVE=38ANDGE(13)=-1ANDSS=0THENPRINT"OK.":SS=1
14230 RETURN

14300 REM 43
14302 DATA 0,0,0,0,0,0,40,0,0,0
14305 PRINT"ICH BIN IN DER PRUNKVOLL AUSGE-"
14306 PRINT"STATTETEN BIBLIOTHEK. EINE ORGEL, DIE"
14307 PRINT"MIR NOCH IN GUTER ERINNERUNG SCHWEBT"
14308 PRINT"STEHT IN EINER ECKE UND DAS RIESIGE"
14309 PRINT"PANORAMAFENSTER IST GEOEFFNET."
14320 IFVE=60ANDOB=27THENPRINT"ALSO, WIR HABEN JETZT WIRKLICH KEINE"
14321 IFVE=60ANDOB=27THENPRINT"ZEIT FUER KINDERSPIELCHEN, PROFESSOR!!"
14322 IFVE=60ANDOB=27THENPRINT"ALSO BITTE KEINE MAETZCHEN MEHR, JA?!?"
14330 RETURN


50000 REM ****************************
50010 REM *     BEFEHLSEINGABE       *
50020 REM *     BEFEHLSZERLEGUNG     *
50030 REM *     BEFEHLSCODIERUNG     *
50040 REM ****************************
50045 G1=0:G2=0
50050 IFUD=1THEN50220
50060 POKE198,0:BE$="":PRINT"WAS NUN ? ";
50070 PRINT"";
50080 GETX$:IFX$=""THEN50080
50085 IFPEEK(203)=1ANDBE$=""THEN50080
50090 IFPEEK(203)=1THENPRINT".":GOTO50140
50095 IFPEEK(203)=1ANDBE$=""THEN50080
50100 I=ASC(X$):IFI<65ORI>90THENIFI<>32ANDI<>32ANDI<>20THEN50080
50110 IFI=20ANDBE$=""THEN50080
50120 IFI=20THENPRINT"  ";:BE$=LEFT$(BE$,LEN(BE$)-1):GOTO50070
50130 PRINT""X$"";:BE$=BE$+X$:GOTO50080
50140 FORI=1TO40:BE$(I)="":NEXT:WZ=1:FORI=1TOLEN(BE$)
50150 :IFMID$(BE$,I,1)=" "THENGOSUB50190:GOTO50180
50160 :IFWZ>40THENPRINT"EINGABE IST ZU LANG !":I=LEN(BE$)+1:GOTO50180
50170 :BE$(WZ)=BE$(WZ)+MID$(BE$,I,1)
50180 NEXTI:GOTO50220
50190 IC=0:FORI1=1TOAZ:IFBE$(WZ)=AU$(I1)THENIC=1
50200 NEXTI1:IFIC=0THENWZ=WZ+1:RETURN
50210 BE$(WZ)="":RETURN
50220 IFUD=1THENUD=0:GOTO50240
50230 WZ=1:VE=0:OB=0
50240 IC=0:G1=0:G2=0
50250 FORI=1TOVZ:IFBE$(WZ)=VE$(I)THENVE=I:IC=1
50251 IFLEN(BE$(WZ))<3THEN50260
50255 IFBE$(WZ)=LEFT$(VE$(I),LEN(BE$(WZ)))THENVE=I-VAL(RIGHT$(VE$(I),1)):IC=1
50260 NEXTI:IFIC=1THEN50350
50270 FORI=1TOGZ:IFBE$(WZ)<>GE$(I)THEN50300
50280 IC=1:IFG1=0THENG1=I
50290 G2=I:IFG2=G1THENG2=0
50300 NEXTI:IFIC=1THEN50350
50310 FORI=1TO32:IFBE$(WZ)=OB$(I)THENOB=I:IC=1
50320 NEXTI:IFIC=1THEN50350
50350 IFBE$(WZ)="UND"THENUD=1:IC=1
50360 IFIC=0THENPRINT"ICH KENNE ";BE$(WZ);" NICHT!":GOTO50050
50370 WZ=WZ+1:IFWZ>40ORBE$(WZ)=""ORUD=1THENRETURN
50380 IC=0:GOTO50250


52000 REM T A B E L L E N
52005 RESTORE 52000

52010 REM VERBTABELLE ------------------
52015 DATA N,S,W,O,SW,SO
52017 DATA NW,NO,RAUF,RUNTER
52020 DATA NIMM,NEHME1,LEGE,VERLIERE1,LEHNE2,LIES,LESE1,ENTZIFFERE2,UNTERSUCHE
52030 DATA SCHAUE1,SCHIESSE,FEUERE1,OEFFNE,SCHLIESSE1,ENTRIEGELE2,SCHWEISSE3
52040 DATA BENUTZE,DREHE1,GEBRAUCHE2,LADE,GEHE,BETRETE1,RUDERE2,KLETTERE3
52050 DATA ERKLETTERE4,ERKLIMME5,BESTEIGE6,SCHNEIDE,ZERSCHNEIDE1,ZERSTOERE3
52060 DATA ENTFERNE4,SCHRAUBE5,ENTSCHRAUBE6,TOETE,WIRF,WERFE1,ESSE,VERSPEISE1
52070 DATA ZERSCHLAGE,SCHLAGE1,GIB,GEBE1,BESTECHE,BESAENFTIGE1,ENTFALTE,BREITE1
52080 DATA SPRINGE,GRABE,BUDDELE1,SPIELE
52090 DATA INVENTUR,LISTE1,SAVE,SPEICHERE1,LOAD,LADE1,HELP,HILFE1
52100 VZ=68:DIMVE$(VZ):FORI=1TOVZ:READVE$(I):NEXT

52200 REM GEGENSTANDSTABELLE -----------
52210 DATA GELD,-2,PISTOLE,-2,SCHLUESSEL,-2,HECKENSCHERE,-2,MESSER,-2
52220 DATA SCHWEISSGERAET,-2,AXT,-2,SCHAUFEL,24,DECKE,24,HONIG,24,ZETTEL,26
52230 DATA BAUPLAENE,-2,WERKZEUG,-2,BUCH,-2,BEUTEL,-2,SCHIFFSSCHRAUBE,42
52240 DATA LEITER,-2,BLAETTER,26
52300 GZ=18:DIMGE$(GZ):DIMGE(GZ):FORI=1TOGZ:READGE$(I):READGE(I):NEXTI

52400 REM OBJEKTTABELLE ----------------
52410 DATA TRUHE,1,LEICHE,1,LAMPE,1,STEUERRAD,2,KANONE,5,GALION,8,SCHAPP,7
52420 DATA BEIBOOT,9,SEIL,10,SCHIFF,11,BUESCHE,20,TUER,21,TUER,22,BAER,27
52430 DATA KRATER,28,BAUM,25,NAUTILUS,29,TUER,30,TUER,31,ANZEIGENTAFEL,31
52440 DATA SAFE,34,BETT,36,KOJE,38,SCHRANK,38,TOILETTE,39,KESSEL,41,ORGEL,43
52450 DATA FENSTER,43,PIRATEN,22,TUER,1,TUER,2,TUER,3
52500 OZ=32:DIMOB$(32):DIMOO(32):FORI=1TO32:READOB$(I):READOO(I):NEXTI

53000 REM AUSSORTIERBARE WOERTERTABELLE-
53005 DATA AB,HIN,AUF,HINAUF,WEG,MIT,DEM,DER,DEN,DIE,DAS,EIN,EINE,EINER,AUS,IN
53010 DATA EINEN, ,NACH,BITTE,ICH,UM,LOS,AN,DURCH,DIR,MIR,IHM,IHR,IHNEN,EUCH,SIE
53015 DATA UEBER,UNTER,VON,VOM,IM,DURCH,AM
53020 AZ=39:DIMAU$(AZ):FORI=1TOAZ:READAU$(I):NEXT
54000 RETURN


60000 REM VERLOREN ---------------------
60001 PRINT"LEIDER HABEN SIE VERLOREN!!"
60002 PRINT"NOCH EINMAL? (J/N)"
60003 GETA$:IFA$<>"J"ANDA$<>"N"THEN60003
60004 IFA$="J"THENRUN
60005 PRINT"               BYE BYE..."
60006 SYS64738


61000 POKE53280,0:POKE53281,0
61001 PRINT"DIESES ADVENTURE VERSTEHT VIELE WORTE."
61002 PRINT"ES DUERFTEN ALSO KAUM SPRACHSCHWIERIG-"
61003 PRINT"KEITEN AUFTAUCHEN. SOLLTE ES DOCH EIN-"
61004 PRINT"MAL SOWEIT SEIN, SO SUCHEN SIE BITTE"
61005 PRINT"EIN ARTVERWANDTES WORT."
61006 PRINT"DAS SPIEL VERSTEHT KOMPLEXE EINGABEN"
61007 PRINT"WIE NIMM DAS MESSER UND O UND S UND"
61008 PRINT"SCHNEIDE DIE BUESCHE UND NIMM SCHWEISS-"
61009 PRINT"GERAET... U.S.W. DIE EINGABEN MUESSEN"
61010 PRINT"SICH JEDOCH AUF 40 WORTE BESCHRAENKEN!"
61011 PRINT"ES IST JEDOCH SINNVOL, ZWEIWORT-"
61012 PRINT"KOMMANDOS ZU BEVORZUGEN, ETWA"
61013 PRINT"NIMM MESSER UND O UND S UND SCHNEIDE"
61014 PRINT"BUESCHE UND NIMM SCHWEISSGERAET..."
61015 PRINT"(MEHRERE SAETZE MUESSEN NICHT ZUSAMMEN-"
61016 PRINT"GESETZT WERDEN!)"
61017 PRINT"VERBEN KOENNEN BIS AUF DREI BUCH-"
61018 PRINT"STABEN GEKUERZT WERDEN, SOLLTEN JEDOCH"
61019 PRINT"WEGEN EVTL. VERWECHSLUNGEN AUSGE-"
61020 PRINT"SCHRIEBEN WERDEN. NOMEN MUESSEN AUS-"
61021 PRINT"GESCHRIEBEN WERDEN, NACH DER SCHREIB-"
61022 PRINT"WEISE IM BESCHREIBUNGSRAUM!!!!"
61023 GETA$:IFA$=""THEN61023


61024 RETURN
62000 POKE53280,0:POKE53281,0
62001 PRINT"LOAD"CHR$(34)"-5"CHR$(34)",8"
62002 PRINT"RUN"
62003 PRINT"":POKE631,13:POKE632,13:POKE198,4
62004 END


62500 PRINT"BITTE KOMBINATION EINGEBEN:";:OPEN1,0:INPUT#1,A:CLOSE1
62501 IFA<>CUTHENPRINT"LEIDER FALSCH!":FORI=1TO2000:NEXT:ZN=34:GOTO1000
62502 IFA=CUTHENPRINT"OK.":SA=1:ZN=34:GOTO1000


63000 PRINT"DIE DISKETTENSEITE IST LEIDER VOLL."
63001 PRINT"SOLL ICH DIE DISKETTE LOESCHEN"
63002 PRINT"ODER VERZICHTEN SIE AUF DIE SPEICHERUNG"
63003 PRINT"DES AUBENGLICKLICHEN SPIELSTANDES?"
63005 PRINT"S-SPEICHERN BEENDEN        F-FORMATIEREN"
63006 GETA$:IFA$<>"S"ANDA$<>"F"THEN63006
63007 IFA$="S"THEN1000
63008 OPEN1,8,15,"S:*"
63009 CLOSE1
63010 GOTO3410


63500 IFGE(4)<>-2THEN1000
63501 IFGE(4)=-2THENPRINT"UND ES LIEGT WAS DANEBEN!":GE(4)=ZN:GOTO1000


63600 REM **********************
63601 REM *    20000 MEILEN    *
63602 REM *   UNTER DEM MEER   *
63603 REM **********************
63604 REM *    WRITTEN BY :    *
63605 REM *  OLIVER LUSCHNATH  *
63606 REM *--------------------*
63607 REM *  MUSIC BY UNKNOWN  *
63608 REM *--------------------*
63609 REM * COPYRIGHT 1988 BY: *
63610 REM *   OLS - SOFTWARE   *
63611 REM **********************


READY.

